nixos-config/flake.nix

{
  inputs = {
    nixpkgs.url = "flake:nixpkgs/nixos-24.05";
    nixpkgs-unstable.url = "flake:nixpkgs/nixos-unstable";
    simple-nixos-mailserver = {
      url = "gitlab:simple-nixos-mailserver/nixos-mailserver/nixos-24.05";
      inputs = {
        nixpkgs.follows = "nixpkgs-unstable";
        nixpkgs-24_05.follows = "nixpkgs";
      };
    };
    dogetipbot-telegram = {
      url = "gitlab:nyanloutre/dogetipbot-telegram/master";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    ipmihddtemp = {
      url = "gitlab:nyanloutre/ipmihddtemp/master";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, nixpkgs-unstable, simple-nixos-mailserver, dogetipbot-telegram, ipmihddtemp }: {

    packages.x86_64-linux = (import ./pkgs nixpkgs.legacyPackages.x86_64-linux);

    nixosConfigurations.paul-fixe = nixpkgs-unstable.lib.nixosSystem {
      system = "x86_64-linux";
      modules = [
        nixpkgs-unstable.nixosModules.notDetected
        {
          nixpkgs.config.allowUnfree = true;
          nix = {
            settings.experimental-features = [ "nix-command" "flakes" ];
            registry = {
              nixpkgs.to = {
                type = "path";
                path = nixpkgs-unstable.legacyPackages.x86_64-linux.path;
              };
            };
          };
        }
        ./systems/PC-Fixe/configuration.nix
      ];
    };

    nixosConfigurations.loutreos = nixpkgs.lib.nixosSystem {
      system = "x86_64-linux";
      specialArgs = { inherit nixpkgs-unstable; };
      modules = [
        nixpkgs-unstable.nixosModules.notDetected
        simple-nixos-mailserver.nixosModule
        dogetipbot-telegram.nixosModule
        ipmihddtemp.nixosModule
        {
          nix = {
            settings.experimental-features = [ "nix-command" "flakes" ];
            registry = {
              nixpkgs.to = {
                type = "path";
                path = nixpkgs.legacyPackages.x86_64-linux.path;
              };
            };
          };
        }
        ./systems/LoutreOS/configuration.nix
      ];
    };

  };
}